0 REM"BASIC INTERPRETE"
1 REM"CBM KERNAL******"
2 REM"SUPRADOS KERNAL3"
3 REM"SUDO3 KERNAL 24P"
4 REM"SUDO3 KERNAL 28P"
5 REM"0123456789ABCDEF"
1000 REM A=ACCU X=X Y=Y
1010 POKE52,32:POKE56,32:CLR
1020 POKE157,128
1030 PRINT"[147]
1040 [153]"FUER WELCHEN COMPUTER TYP (1/2)
1050 PRINT"1  C64 ALT       24PIN ROM
1060 [153]"2  C64 NEU C128  28PIN ROM
1070 GETA$:IFA$<>"1"ANDA$<>"2"THEN1070
1080 IFA$="2"THEN1150
1090 POKE198,0:INPUT"LEGEN SIE DIE QUELLDISK EIN U. DRUECKEN SIE RETURN";A$
1100 Y=32:LN=31:HN=8:GOSUB1380
1110 Y=64:LN=55:HN=8:GOSUB1380
1120 LN=79
1130 Y=96
1140 GOTO1220:REM-----------------------
1150 POKE198,0:INPUT"LEGEN SIE DIE QUELLDISK EIN U. DRUECKEN SIE RETURN";A$
1160 Y=32:LN=7:HN=8:GOSUB1380
1170 Y=64:LN=31:HN=8:GOSUB1380
1180 Y=96:LN=7:HN=8:GOSUB1380
1190 Y=128:LN=55:HN=8:GOSUB1380
1200 LN=103
1210 Y=160
1220 PRINT
1230 POKE198,0:INPUT"LEGEN SIE DIE ZIELDISK EIN UND DRUECKEN SIE RETURN";A$
1240 OPEN15,8,15,"I":CLOSE15
1250 HN=8
1260 POKE780,252:REM ZEIGER AUF START
1270 POKE781,0:REM LOW ENDE
1280 POKE782,Y:REM HIGH ENDE
1290 POKE252,0  :REM START LOW
1300 POKE253,32 :REM START HIGH
1310 POKE186,8:REM GERAETEADRESSE
1320 POKE183,16:REM LAENGE D.NAMENS
1330 POKE187,LN:REM LOW ANFANG NAME
1340 POKE188,HN:REM HIGH ANFANG NAME
1350 SYS65496:REM SAVE
1360 OPEN15,8,15:INPUT#15,A,B$,C,D:CLOSE15:PRINT:PRINTA;B$;C;D:IFA>0THENEND
1370 END
1380 REM LOAD -------------------------
1390 POKE780,0:REM =LOAD
1400 POKE781,0:REM START HIGH
1410 POKE782,Y:REM START LOW
1420 POKE186,8:REM GERAETEADRESSE
1430 POKE185,0:REM ABSOLUT LADEN
1440 POKE183,16:REM LAENGE D.NAMENS
1450 POKE187,LN:REM LOW ANFANG NAME
1460 POKE188,HN:REM HIGH ANFANG NAME
1470 SYS65493:REM LOAD
1480 OPEN15,8,15:INPUT#15,A,B$,C,D:CLOSE15:PRINT:PRINTA;B$;C;D:IFA>0THENEND
1490 RETURN